#| Utilities for interacting with the idris compiler and package manager
unit module IUtils::Compiler;

# Utility functions for pack

#| Invoke a pack command
sub pack-run(*@cmd) is export {
    my $proc = run "pack",  @cmd, :out, :err;
    my $out = $proc.out.slurp(:close);
    my $err = $proc.err.slurp(:close);
    unless $proc {
        die qq:to/END/;
        Pack Failure!
        Captured Output:
        $out

        Captured StdErr:
        $err
        END
    }
}

#| Build a package with pack
sub pack-build($pkg) is export {
    pack-run 'build', $pkg
}

#| Test a package with pack
sub pack-test($pkg) is export {
    pack-run 'build', $pkg
}

#| Clean a package with pack
sub pack-clean($pkg) is export {
    pack-run 'clean', $pkg
}

# Utility functions for idris

#| An error coming from the idris compiler
class IdrisError is Exception {
    has Str $.out;
    has Str $.err;
    has Int $.exit-code;
    has Str $.command;

    method message {
        qq:to/END/;
        Error running idris command: $.command
        Command exited with $.exit-code
        END
    }
}

#| An error coming from a compiled expression
class ExpressionError is Exception {
    has Str $.out;
    has Str $.err;
    has Int $.exit-code;
    has Str $.expr;

    method message {
        qq:to/END/;
        Error running expression: $.expr
        Command exited with $.exit-code
        END
    }
}

#| Invoke an idris command
sub idris-run(*@cmd) is export {
    my $proc = run "idris2",  @cmd, :out, :err;
    my $out = $proc.out.slurp(:close);
    my $err = $proc.err.slurp(:close);
    unless $proc {
        IdrisError.new(
            out => $out, err => $err,
            exit-code => $proc.exitcode, command => @cmd.Str)
        .throw;
    }
    return $out;
}

# TODO: Special handling for IO Bool to make this eaiser
#| Exec the expression with the given name in the given file
sub idris-exec($expr, $file) is export {
    # Have idris compile an executable for the expression,
    idris-run '--find-ipkg', '--client', ":c iutils_out $expr", $file;
    # Run the expression
    my $proc = run 'build/exec/iutils_out', :out, :err;
    my $out = $proc.out.slurp(:close);
    my $err = $proc.err.slurp(:close);
    unless $proc {
        ExpressionError.new(
            out => $out, err => $err,
            exit-code => $proc.exitcode, expr => $expr
        ).throw;
    }
    return $out;
}