System/home-manager/linux/programs/image-editing.nix

{ config, lib, pkgs, inputs, ... }:
let unstable = inputs.nixpkgs-unstable.legacyPackages."${pkgs.system}";
in {
  config = lib.mkIf config.nathan.programs.image-editing {
    home.packages = with pkgs;
      let
        orcaAppimage = pkgs.fetchzip {
          url =
            "https://github.com/SoftFever/OrcaSlicer/releases/download/v1.6.4-beta/OrcaSlicer_V1.6.4-beta_Linux.zip";
          sha256 = "sha256-e9CbLBnWC2RuLM8CflKgA45svczS1yh8Mp6WUynS1BY=";
        };
        orcaSlicer = appimageTools.wrapType2 {
          name = "OrcaSlicer";
          src = "${orcaAppimage}/OrcaSlicer_ubu64.AppImage";
          extraPkgs = pkgs: with pkgs; [ webkitgtk ];
        };
      in [
        # RawTherapee for raw editing
        unstable.rawtherapee
        # Gimp for complex editing
        gimp-with-plugins
        # Krita for drawing
        unstable.krita
        # Xournal for recording notes
        xournalpp
        # Pinta for basic image editing
        unstable.pinta
        # Command line tools for image conversion and handling
        imagemagickBig
        ## 3d printing
        # Orca Slicer
        appimage-run
        orcaSlicer
        ## Cad Software
        python311Packages.cadquery
        cq-editor
      ];
  };
}