Factor out post generation components

lib/Render/Post.rakumod

@@ -0,0 +1,100 @@
+use v6.e.PREVIEW;
+unit module Render::Post;
+
+use Render::Util;
+use DB::Post;
+
+use HTML::Functional;
+
+sub post-date(Post:D $post) is export {
+    my $datetime = $post.posted-at;
+    my $timestamp = sprintf(
+        "%s %02d:%02d%s",
+        $datetime.yyyy-mm-dd,
+        ($datetime.hour % 12) || 12,
+        $datetime.minute,
+        $datetime.hour < 12 ?? 'am' !! 'pm'
+    );
+
+    div :class<post-time>, :title("Posted At $timestamp"), [
+        icon 'time';
+        '&nbsp;';
+        $timestamp
+    ]
+}
+
+sub post-edit(Post:D $post) is export {
+    return [] unless $post.edited-at.elems;
+    my $datetime = $post.edited-at.max;
+    my $timestamp = sprintf(
+        "%s %02d:%02d%s",
+        $datetime.yyyy-mm-dd,
+        ($datetime.hour % 12) || 12,
+        $datetime.minute,
+        $datetime.hour < 12 ?? 'am' !! 'pm'
+    );
+
+    div :class<post-edit>, :title("Last Edited At $timestamp"), [
+        icon 'edit';
+        '&nbsp;';
+        $timestamp
+    ]
+}
+
+sub post-read-time(Post:D $post) is export {
+    my ($slow, $average, $fast) = $post.readtimes;
+    div :class<post-read-time>, :title<Estimated read time at 140/180/220 WPM>, [
+        icon 'timer';
+        '&nbsp;';
+        mins-to-string $slow;
+        '&nbsp;';
+        '/';
+        '&nbsp;';
+        mins-to-string $average;
+        '&nbsp;';
+        '/';
+        '&nbsp;';
+        mins-to-string $fast;
+    ]
+}
+
+sub post-tag(Str:D $tag) is export {
+    span :class<post-tag>, [
+        a :href("/tags/$tag.html"), [
+            icon 'hash';
+            $tag;
+        ]
+    ]
+}
+
+sub post-tags(Post:D $post) is export {
+    my @tags = $post.tags;
+    if @tags {
+       @tags.=map(*.&post-tag);
+       div :class<post-tags>, [
+           icon 'purchase-tag-alt';
+           '&nbsp;';
+           intersperse(', ', @tags);
+       ]
+    } else {
+        []
+    }
+}
+
+sub post-info(Post:D $post) is export {
+    div :class<post-info>, [
+        post-date $post;
+        post-edit $post;
+        post-read-time $post;
+        post-tags $post;
+    ];
+}
+
+sub post-header(Post:D $post) is export {
+    header :class<post-header>, [
+        div :class<post-title>, [
+            h1 $post.title;
+        ];
+        post-info $post;
+    ]
+}

lib/Render/Util.rakumod

@@ -35,3 +35,20 @@ sub post-link(Int:D $id, Post:D $post --> Str:D) is export {
 sub icon($icon) is export {
     i(:class("bx bx-$icon"))
 }
+
+sub mins-to-string($mins) is export {
+    if $mins < 60 {
+        $mins.Str ~ "m"
+    } else {
+        my $h = $mins div 60;
+        my $m = $mins mod 60;
+        $h.Str ~ "h" ~ $m.Str ~ "m"
+    }
+}
+
+sub intersperse (\element, +list) is export {
+    gather for list {
+        FIRST .take, next;
+        take slip element, $_;
+    }
+}